[erledigt] Fensterüberwachung und Alarmierung

[buempi]

Hallo Honk

Auch das kann man lösen mit einem weiteren "sonst":

Code: Alles auswählen

wenn Fenster_Alarm = "Alarm" dann

   wenn Raumregler_Arbeitszimmer.Fenster = "geoeffnet"
   oder Raumregler_Badezimmer.Fenster = "geoeffnet" dann
      Alarm einschalten
   sonst
      Alarm ausschalten
   endewenn

sonst

   Alarm ausschalten

endewenn

Viele Grüsse
Bümpi

[honk0504]

Das war es!!
Danke.

[honk0504]

Eine Sache habe ich da doch noch ...
Ich habe eine Anzeige1 mit der Bezeichnung Alarm. Wie kann ich die Alarmierung in diese Anzeige umleiten?
Sowas wie

Code: Alles auswählen

30.12.2009 14:00:00  Das Fenster blablabla wurde geöffnet!

[buempi]

Hallo Honk

Das Objekt Anzeige1 muss vom Typ Zeichen sein. Dann kannst du am Schluss des Makros folgende Erweiterung vornehmen:

Code: Alles auswählen

wenn Alarm eingeschaltet dann

   Anzeige1 := Zeit + " Fenster"

   wenn Raumregler_Arbeitszimmer.Fenster = "geoeffnet" dann
      Anzeige1 := Anzeige1 + " Arbeitszimmer"
   endewenn

   wenn Raumregler_Badezimmer = "geoeffnet" dann
      Anzeige1 := Anzeige1 + " Badezimmer"
   endewenn

   Anzeige1 := Anzeige1 + " offen"

sonst

   Anzeige1 := ""

endewenn

So werden auch mehrere offene Fenster angezeigt; vorausgesetzt, das Objekt wurde in der Visualisierung genügend breit gemacht.

Viele Grüsse
Bümpi

[honk0504]

Genau so! SUPER!
Eine letzte Sache noch: ich habe schon einen Alarm (Garagentor ist offen/geschlossen) der in die Anzeige1 schreibt.
Wenn nun der Alarm "Fenster xyz offen!" kommt wird die Meldung Garagentor überschrieben. Oder anders gesagt; es wird in die gleiche Zeile geschrieben. Wie kann ich definieren in welche Zeilen in der MeldungsTextBox geschieben werden soll?

[buempi]

Wie kann ich definieren in welche Zeilen in der MeldungsTextBox geschieben werden soll?

Das geht mit Homeputer nicht. Entweder verwendest du für jede Fehlermeldung ein eigenes Zeichenobjekt, oder du setzst alle Fehlermeldungen (Fenster, Garagetor usw.) in nur einem einzigen Makro zusammen:

Code: Alles auswählen

Anzeige1 := ""

wenn Garagetor = "offen" dann
   Anzeige1 := "Garagetor offen<<"
endewenn

wenn Fenster_Alarm = "Alarm" und Raumregler_Badezimmer.Fenster = "geoeffnet" dann
   Anzeige1 := Anzeige1 + "Fenster Bad offen<<"
endewenn

** usw.

Die << bewirken einen Zeilenumbruch.

Viele Grüsse
Bümpi

[honk0504]

Ich habe das jetzt mal bei mir umgesetzt (richtig wie ich hoffe).
Guckst Du hier:

Code: Alles auswählen

Anzeige2 := ""

wenn Raumregler_Arbeitszimmer.Fenster = "geoeffnet"
  oder Raumregler_Badezimmer.Fenster = "geoeffnet"
  oder Raumregler_Wohnzimmer.Fenster = "geoeffnet" dann
  Fenster_Alarm einschalten
  Anzeige2 := Datum+" "+Uhrzeit+" Fenster"

  wenn Raumregler_Arbeitszimmer.Fenster = "geoeffnet" dann
   Anzeige2 := Anzeige2 + " Arbeitszimmer"
  endewenn
  wenn Raumregler_Badezimmer.Fenster = "geoeffnet" dann
   Anzeige2 := Anzeige2 + " Badezimmer"
  endewenn
  wenn Raumregler_Wohnzimmer.Fenster = "geoeffnet" dann
   Anzeige2 := Anzeige2 + " Wohnzimmer"
  endewenn
  Anzeige2 := Anzeige2 + " offen!<<"
 sonst
  Fenster_Alarm ausschalten
  Anzeige2:="Alle Fenster sind geschlossen!<<"
endewenn

wenn Garagentor1 geoeffnet dann
 Anzeige2 := Datum+" "+Uhrzeit+" Das Garagentor ist offen!"
sonst
 Anzeige2 := "Das Garagentor ist geschlossen!"
endewenn

Ausführungsintervall: alle 5 Sek.

Es zeigt jedoch nur "Das Garagentor ist geschlossen!" an. ???

Ich habe es auch schon mit

Code: Alles auswählen

...
Anzeige2:="Alle Fenster sind geschlossen!"+"<<"
...

versucht. Kein Erfolg.

[buempi]

Hallo Honk

Durch den Garagetor-WENN-Block wird alles, was über Fenster vorher in die Anzeige2 geschrieben wurde, überschrieben. Man darf also hier auch nur anhängen!

Statt "Datum" + "Uhrzeit" kannst du auch "Zeit" verwenden. Da kommt beides. Würde ich aber weglassen, da durch den 5-Sekunden-Intervall ja eh immer nur die aktuelle Zeit drin steht.

Den "Garage"-Teil also wie folgt ändern:

Code: Alles auswählen

wenn Garagentor1 = "offen" dann
   Anzeige2 := Anzeige2 + "Das Garagentor ist offen!"
sonst
   Anzeige2 := Anzeige2 + "Das Garagentor ist geschlossen!"
endewenn

Viele Grüsse
Bümpi

[honk0504]

Genau so wollte ich es haben ... !
Bümpi; Du bist der Beste! DANKE.
Jetzt stimmt auch der Status -> erledigt.